#$ -S /bin/csh -v
#
# Job submission script for program ECLOUD
# For details on using the grid batch submission queues
# see http://www.lepp.cornell.edu/~critten/cesr/grid 
#
# Specify architecture for linux pc farm submission
#$ -l arch=lx24-x86
#
echo === Background job submission script for program ECLOUD ===
# 2 February 2006 J.A.Crittenden
#
echo === Begin compile step ...
cd $HOME/ecloud
gmake 
set stat=$status
echo === Compile finished ===  status: $stat
#
if ( $stat == 0 ) then
echo === ... Compile finished successfully === 
#
@ jobid = 1
set workdir=job"$jobid"
while ( -e $workdir ) 
#    echo Job $jobid already exists, increment job number
    @ jobid++
    set workdir = job"$jobid"
end
#
echo The job ID number is $jobid
echo Creating output directory $workdir
#
mkdir $workdir
cp ecloud.input $workdir/ecloud_"$jobid".input
cd $workdir
ln -sf ecloud_"$jobid".input ecloud.input
cp ../ecloud.f .

#
# Create the submission batch script
if (-e batch_script) rm batch_script
echo "#$ -S /bin/csh" >batch_script
echo "#$ -l arch=lx24-x86" >> batch_script
echo "cd $HOME/ecloud/$workdir" >> batch_script
echo "../xecloud" >> batch_script
#
  echo === Submit background job with log file ecloud_"$jobid".log.onnnn ===
   qsub -N ecloud_"$jobid".log -o $HOME/ecloud/$workdir  batch_script
#
else
  echo === Compile failed ===  status: $stat
endif
exit